In [1]:

using Hecke

Quaternion algebras¶

Creation¶

In [2]:

Q = quaternion_algebra(QQ, -1, -1)

Out[2]:

Quaternion algebra
  over rational field
  defined by i^2 = -1, j^2 = -1

Construct the standard basis:

In [3]:

_, i, j, k = basis(Q)

Out[3]:

4-element Vector{AssociativeAlgebraElem{QQFieldElem, Hecke.QuaternionAlgebra{QQFieldElem}}}:
 1
 i
 j
 k

Verifying the relations:

In [4]:

i^2 == -1 && j^2 == -1 && i * j == k

Out[4]:

true

Construction of elements:

In [5]:

alpha = 1 + 2*i + 3*j

Out[5]:

1 + 2*i + 3*j

Or via directly supplying the coordinates as a vector:

In [6]:

alpha == Q([1, 2, 3, 0])

Out[6]:

true

This works for also for number fields:

In [7]:

K, sqrt2 = quadratic_field(2)
Q = quaternion_algebra(K, sqrt2, K(3))
alpha = Q([sqrt2, 1, 0, 1])

Out[7]:

sqrt(2) + i + k

Properties of elements¶

Get the coefficients with respect to the canonical basis:

In [8]:

coefficients(alpha)

Out[8]:

4-element Vector{AbsSimpleNumFieldElem}:
 sqrt(2)
 1
 0
 1

Trace and norm (also reduced version)

In [9]:

tr(alpha), norm(alpha)

Out[9]:

(4*sqrt(2), 8*sqrt(2) + 12)

In [10]:

trred(alpha), normred(alpha)

Out[10]:

(2*sqrt(2), 2*sqrt(2) + 2)

Image of elements under canonical involution:

In [11]:

conjugate(alpha)

Out[11]:

sqrt(2) - i - k

In [12]:

normred(alpha) == conjugate(alpha) * alpha

Out[12]:

true

Division¶

For division there are the two functions divexact_left and divexact_right. If c = divexact_right(a, b), then a == c * b. So, divexact_right(a, b) returns an element c, such that b becomes a right-divisor of a.

In [13]:

_, i, j, k = basis(Q);

In [14]:

divexact_right(k, j)

Out[14]:

i

In [15]:

k == i * j

Out[15]:

true

In [16]:

divexact_left(k, j)

Out[16]:

-i

In [17]:

k == j * (-i)

Out[17]:

true

Polynomials¶

Polynomials behave very much like polynonomials over commutative rings, except that everything related to divisions needs to specifiy the "side".

In [18]:

Q = quaternion_algebra(QQ, -1, -1)
_, i, j, k = basis(Q)
Qx, x = Q[:x]
f = i * x^2 + j * x
g = i * x

Out[18]:

i*x

In [19]:

divexact_right(f, g) == x + k

Out[19]:

true

In [20]:

divexact_left(f, g) == x + (- k)

Out[20]:

true

In [21]:

Hecke.divrem_right(f, g)

Out[21]:

(x + k, 0)

In [22]:

Hecke.gcd_right(f, g)

Out[22]:

i*x

Splitting of quaternion algebras¶

In [23]:

Q = quaternion_algebra(QQ, -1, -1)
is_split(Q)

Out[23]:

false

In [24]:

Q = quaternion_algebra(QQ, 1, -1)
is_split(Q)

Out[24]:

true

In [25]:

is_split_with_zero_divisor(Q)

Out[25]:

(true, 1 + i)

Solving norm equations¶

Let's solve a norm equation. We want to check whether $2$ is a norm of $\mathbf{Q}(\sqrt{2})$ .

In [26]:

K, sqrt2 = quadratic_field(2)

Out[26]:

(Real quadratic field defined by x^2 - 2, sqrt(2))

In [27]:

fl, a = is_norm(K, 2);

In [28]:

fl

Out[28]:

true

Since elements with given norm are in general large, they are represented in special "factored" form:

In [29]:

Out[29]:

(sqrt(2) + 64)^1*89^-1*(sqrt(2) + 25)^1*(sqrt(2) + 4)^-2*23^-1*1^-1*(sqrt(2) + 5)^1*7^1*(sqrt(2) + 3)^-1*sqrt(2)^2

We can turn this into an ordinary elements using evaluate:

In [30]:

b = evaluate(a)

Out[30]:

-sqrt(2) + 2

In [31]:

norm(b) == 2

Out[31]:

true

If we know that a norm equation has a solution, we can directly ask for it:

In [32]:

norm_equation(K, 2)

Out[32]:

-sqrt(2) + 2

Representation by binary quadratic forms¶

Assume that we have two diagonal quadratic forms $q_1 = \langle a_1, a_2 \rangle$ and $q_2 = \langle b_1, b_2 \rangle$ over a field $K$ . We want to find an element $d$ , which is represented both by $q_1$ and $q_2$ .

In [33]:

K = QQ;

In [34]:

a1, a2 = 2, 3

Out[34]:

(2, 3)

In [35]:

b1, b2 = 3, 4

Out[35]:

(3, 4)

We form the quadratic form $q = \langle a_1, a_2, -b_1, -b_2\rangle$ . Then the task becomes finding an isotropic vector.

In [36]:

q = quadratic_space(K, diagonal_matrix(K, [a1, a2, -b1, b2]));

Checking whether such an isotropic vector exists:

In [37]:

is_isotropic(q)

Out[37]:

true

In [38]:

fl, v = is_isotropic_with_vector(q)

Out[38]:

(true, QQFieldElem[0, -1//6, 1//6, 0])

To extract the element $d$ , we need to evaluate the quadratic form:

In [39]:

d = v[1]^2 * a1 + v[2]^2 * a2

Out[39]:

1//12

In [40]:

v[1]^2 * a1 + v[2]^2 * a2 == v[3]^2 * b1 + v[4]^2 * b2

Out[40]:

true