Simon-Mars tensor and Kerr spacetime

This notebook demonstrates a few capabilities of SageMath in computations regarding the Simon-Mars tensor. The corresponding tools have been developed within the SageManifolds project (version 1.3, as included in SageMath 8.3).

Click here to download the notebook file (ipynb format). To run it, you must start SageMath within the Jupyter notebook, via the command sage -n jupyter

NB: a version of SageMath at least equal to 8.2 is required to run this notebook:

version()

'SageMath version 8.3, Release Date: 2018-08-03'

First we set up the notebook to display mathematical objects using LaTeX rendering:

%display latex

Since some computations are quite long, we ask for running them in parallel on 8 cores:

Parallelism().set(nproc=8)

Spacetime manifold

We declare the Kerr spacetime (or more precisely the part of the Kerr spacetime covered by Boyer-Lindquist coordinates) as a 4-dimensional Lorentzian manifold $\mathcal{M}$:

M = Manifold(4, 'M', latex_name=r'\mathcal{M}',
             structure='Lorentzian')
print(M)

4-dimensional Lorentzian manifold M

The standard Boyer-Lindquist coordinates $(t,r,\theta,\phi)$ are introduced by declaring a chart $X$ on $\mathcal{M}$, via the method chart(), the argument of which is a string expressing the coordinates names, their ranges (the default is $(-\infty,+\infty)$) and their LaTeX symbols:

X.<t,r,th,ph> = M.chart(r't r:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\phi') 
print(X) ; X

Chart (M, (t, r, th, ph))

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\mathcal{M},(t, r, {\theta}, {\phi})\right)$$

Metric tensor

The 2 parameters $m$ and $a$ of the Kerr spacetime are declared as symbolic variables:

var('m, a', domain='real')

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(m, a\right)$$

Let us set the components of the spacetime metric in the coordinate frame associated with Boyer-Lindquist coordinates, which is the current manifold's default frame:

g = M.metric()
rho2 = r^2 + (a*cos(th))^2
Delta = r^2 -2*m*r + a^2
g[0,0] = -(1-2*m*r/rho2)
g[0,3] = -2*a*m*r*sin(th)^2/rho2
g[1,1], g[2,2] = rho2/Delta, rho2
g[3,3] = (r^2+a^2+2*m*r*(a*sin(th))^2/rho2)*sin(th)^2
g.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}g = \left( \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} - 1 \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( \frac{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}{a^{2} - 2 \, m r + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( a^{2} \cos\left({\theta}\right)^{2} + r^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + {\left(\frac{2 \, a^{2} m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} + a^{2} + r^{2}\right)} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$$

g[:]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrr} \frac{2 \, m r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} - 1 & 0 & 0 & -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ 0 & \frac{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}{a^{2} - 2 \, m r + r^{2}} & 0 & 0 \\ 0 & 0 & a^{2} \cos\left({\theta}\right)^{2} + r^{2} & 0 \\ -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} & 0 & 0 & {\left(\frac{2 \, a^{2} m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} + a^{2} + r^{2}\right)} \sin\left({\theta}\right)^{2} \end{array}\right)$$

The Levi-Civita connection $\nabla$ associated with $g$:

nabla = g.connection() ; print(nabla)

Levi-Civita connection nabla_g associated with the Lorentzian metric g on the 4-dimensional Lorentzian manifold M

As a check, we verify that the covariant derivative of $g$ with respect to $\nabla$ vanishes identically:

nabla(g).display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\nabla_{g} g = 0$$

Killing vector

The default vector frame on the spacetime manifold is the coordinate basis associated with Boyer-Lindquist coordinates:

M.default_frame() is X.frame()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

X.frame()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\mathcal{M}, \left(\frac{\partial}{\partial t },\frac{\partial}{\partial r },\frac{\partial}{\partial {\theta} },\frac{\partial}{\partial {\phi} }\right)\right)$$

Let us consider the first vector field of this frame:

xi = X.frame()[0] ; xi

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{\partial}{\partial t }$$

print(xi)

Vector field d/dt on the 4-dimensional Lorentzian manifold M

The 1-form associated to it by metric duality is

xi_form = xi.down(g)
xi_form.set_name('xi_form', r'\underline{\xi}')
print(xi_form) ; xi_form.display()

1-form xi_form on the 4-dimensional Lorentzian manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\underline{\xi} = \left( -\frac{a^{2} \cos\left({\theta}\right)^{2} - 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} t + \left( -\frac{2 \, a m r \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}$$

Its covariant derivative is

nab_xi = nabla(xi_form)
print(nab_xi) ; nab_xi.display()

Tensor field nabla_g(xi_form) of type (0,2) on the 4-dimensional Lorentzian manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\nabla_{g} \underline{\xi} = \left( \frac{a^{2} m \cos\left({\theta}\right)^{2} - m r^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} t\otimes \mathrm{d} r + \left( \frac{2 \, a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} t\otimes \mathrm{d} {\theta} + \left( -\frac{a^{2} m \cos\left({\theta}\right)^{2} - m r^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} r\otimes \mathrm{d} t + \left( \frac{{\left(a^{3} m \cos\left({\theta}\right)^{2} - a m r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} r\otimes \mathrm{d} {\phi} + \left( -\frac{2 \, a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} t + \left( \frac{2 \, {\left(a^{3} m r + a m r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\phi} + \left( -\frac{{\left(a^{3} m \cos\left({\theta}\right)^{2} - a m r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} r + \left( -\frac{2 \, {\left(a^{3} m r + a m r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\theta}$$

Let us check that the Killing equation is satisfied:

nab_xi.symmetrize().display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}0$$

Equivalently, we check that the Lie derivative of the metric along $\xi$ vanishes:

g.lie_der(xi).display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}0$$

Thank to Killing equation, $\nabla_g \underline{\xi}$ is antisymmetric. We may therefore define a 2-form by $F := - \nabla_g \xi$. Here we enforce the antisymmetry by calling the function antisymmetrize() on nab_xi:

F = - nab_xi.antisymmetrize()
F.set_name('F')
print(F)
F.display()

2-form F on the 4-dimensional Lorentzian manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}F = \left( -\frac{a^{2} m \cos\left({\theta}\right)^{2} - m r^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} t\wedge \mathrm{d} r + \left( -\frac{2 \, a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} t\wedge \mathrm{d} {\theta} + \left( -\frac{{\left(a^{3} m \cos\left({\theta}\right)^{2} - a m r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} r\wedge \mathrm{d} {\phi} + \left( -\frac{2 \, {\left(a^{3} m r + a m r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\theta}\wedge \mathrm{d} {\phi}$$

We check that

F == - nab_xi

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

The squared norm of the Killing vector is:

lamb = - g(xi,xi)
lamb.set_name('lambda', r'\lambda')
print(lamb)
lamb.display()

Scalar field lambda on the 4-dimensional Lorentzian manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} \lambda:& \mathcal{M} & \longrightarrow & \mathbb{R} \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & \frac{a^{2} \cos\left({\theta}\right)^{2} - 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \end{array}$$

Instead of invoking $g(\xi,\xi)$, we could have evaluated $\lambda$ by means of the 1-form $\underline{\xi}$ acting on the vector field $\xi$:

lamb == - xi_form(xi)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

or, using index notation as $\lambda = - \xi_a \xi^a$:

lamb == - ( xi_form['_a']*xi['^a'] )

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

Curvature

The Riemann curvature tensor associated with $g$ is

Riem = g.riemann()
print(Riem)

Tensor field Riem(g) of type (1,3) on the 4-dimensional Lorentzian manifold M

The component $R^0_{\ \, 123} = R^t_{\ \, r\theta\phi}$ is

Riem[0,1,2,3]

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{{\left({\left(a^{7} m - 2 \, a^{5} m^{2} r + a^{5} m r^{2}\right)} \cos\left({\theta}\right)^{5} - {\left(3 \, a^{7} m - 2 \, a^{5} m^{2} r + 8 \, a^{5} m r^{2} - 6 \, a^{3} m^{2} r^{3} + 5 \, a^{3} m r^{4}\right)} \cos\left({\theta}\right)^{3} + 3 \, {\left(3 \, a^{5} m r^{2} - 2 \, a^{3} m^{2} r^{3} + 5 \, a^{3} m r^{4} + 2 \, a m r^{6}\right)} \cos\left({\theta}\right)\right)} \sin\left({\theta}\right)}{a^{2} r^{6} - 2 \, m r^{7} + r^{8} + {\left(a^{8} - 2 \, a^{6} m r + a^{6} r^{2}\right)} \cos\left({\theta}\right)^{6} + 3 \, {\left(a^{6} r^{2} - 2 \, a^{4} m r^{3} + a^{4} r^{4}\right)} \cos\left({\theta}\right)^{4} + 3 \, {\left(a^{4} r^{4} - 2 \, a^{2} m r^{5} + a^{2} r^{6}\right)} \cos\left({\theta}\right)^{2}}$$

The Ricci tensor:

Ric = g.ricci()
print(Ric)

Field of symmetric bilinear forms Ric(g) on the 4-dimensional Lorentzian manifold M

Let us check that the Kerr metric is a vacuum solution of Einstein equation, i.e. that the Ricci tensor vanishes identically:

Ric.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{Ric}\left(g\right) = 0$$

The Weyl conformal curvature tensor is

C = g.weyl()
print(C)

Tensor field C(g) of type (1,3) on the 4-dimensional Lorentzian manifold M

Let us exhibit two of its components $C^0_{\ \, 123}$ and $C^0_{\ \, 101}$:

C[0,1,2,3]

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{{\left({\left(a^{7} m - 2 \, a^{5} m^{2} r + a^{5} m r^{2}\right)} \cos\left({\theta}\right)^{5} - {\left(3 \, a^{7} m - 2 \, a^{5} m^{2} r + 8 \, a^{5} m r^{2} - 6 \, a^{3} m^{2} r^{3} + 5 \, a^{3} m r^{4}\right)} \cos\left({\theta}\right)^{3} + 3 \, {\left(3 \, a^{5} m r^{2} - 2 \, a^{3} m^{2} r^{3} + 5 \, a^{3} m r^{4} + 2 \, a m r^{6}\right)} \cos\left({\theta}\right)\right)} \sin\left({\theta}\right)}{a^{2} r^{6} - 2 \, m r^{7} + r^{8} + {\left(a^{8} - 2 \, a^{6} m r + a^{6} r^{2}\right)} \cos\left({\theta}\right)^{6} + 3 \, {\left(a^{6} r^{2} - 2 \, a^{4} m r^{3} + a^{4} r^{4}\right)} \cos\left({\theta}\right)^{4} + 3 \, {\left(a^{4} r^{4} - 2 \, a^{2} m r^{5} + a^{2} r^{6}\right)} \cos\left({\theta}\right)^{2}}$$

C[0,1,0,1]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{3 \, a^{4} m r \cos\left({\theta}\right)^{4} + 3 \, a^{2} m r^{3} + 2 \, m r^{5} - {\left(9 \, a^{4} m r + 7 \, a^{2} m r^{3}\right)} \cos\left({\theta}\right)^{2}}{a^{2} r^{6} - 2 \, m r^{7} + r^{8} + {\left(a^{8} - 2 \, a^{6} m r + a^{6} r^{2}\right)} \cos\left({\theta}\right)^{6} + 3 \, {\left(a^{6} r^{2} - 2 \, a^{4} m r^{3} + a^{4} r^{4}\right)} \cos\left({\theta}\right)^{4} + 3 \, {\left(a^{4} r^{4} - 2 \, a^{2} m r^{5} + a^{2} r^{6}\right)} \cos\left({\theta}\right)^{2}}$$

To form the Simon-Mars tensor, we need the fully covariant (type-(0,4) tensor) form of the Weyl tensor (i.e. $C_{\alpha\beta\mu\nu} = g_{\alpha\sigma} C^\sigma_{\ \, \beta\mu\nu}$); we get it by lowering the first index with the metric:

Cd = C.down(g)
print(Cd)

Tensor field of type (0,4) on the 4-dimensional Lorentzian manifold M

The (monoterm) symmetries of this tensor are those inherited from the Weyl tensor, i.e. the antisymmetry on the last two indices (position 2 and 3, the first index being at position 0):

Cd.symmetries()

no symmetry; antisymmetry: (2, 3)

Actually, Cd is also antisymmetric with respect to the first two indices (positions 0 and 1), as we can check:

Cd == Cd.antisymmetrize(0,1)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

To take this symmetry into account explicitely, we set

Cd = Cd.antisymmetrize(0,1)

Hence we have now

Cd.symmetries()

no symmetry; antisymmetries: [(0, 1), (2, 3)]

Simon-Mars tensor

The Simon-Mars tensor with respect to the Killing vector $\xi$ is a rank-3 tensor introduced by Marc Mars in 1999 (Class. Quantum Grav. 16, 2507). It has the remarkable property to vanish identically if, and only if, the spacetime $(\mathcal{M},g)$ is locally isometric to a Kerr spacetime.

Let us evaluate the Simon-Mars tensor by following the formulas given in Mars' article. The starting point is the self-dual complex 2-form associated with the Killing 2-form $F$, i.e. the object $\mathcal{F} := F + i \, {}^* F$, where ${}^*F$ is the Hodge dual of $F$:

FF = F + I * F.hodge_dual(g)
FF.set_name('FF', r'\mathcal{F}') ; print(FF)

2-form FF on the 4-dimensional Lorentzian manifold M

FF.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathcal{F} = \left( \frac{-2 i \, a m r \sqrt{\cos\left({\theta}\right) + 1} \sqrt{-\cos\left({\theta}\right) + 1} \cos\left({\theta}\right) - {\left(a^{2} m \cos\left({\theta}\right)^{2} - m r^{2}\right)} \sin\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}\right)} \sin\left({\theta}\right)} \right) \mathrm{d} t\wedge \mathrm{d} r + \left( -\frac{2 \, a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right) - {\left(i \, a^{3} m \cos\left({\theta}\right)^{2} - i \, a m r^{2}\right)} \sqrt{\cos\left({\theta}\right) + 1} \sqrt{-\cos\left({\theta}\right) + 1}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} t\wedge \mathrm{d} {\theta} + \left( \frac{-2 i \, a^{2} m r \sqrt{\cos\left({\theta}\right) + 1} \sqrt{-\cos\left({\theta}\right) + 1} \cos\left({\theta}\right) \sin\left({\theta}\right) - {\left(a^{3} m \cos\left({\theta}\right)^{2} - a m r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} r\wedge \mathrm{d} {\phi} + \left( -\frac{2 \, {\left(a^{3} m r + a m r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right) - {\left(-i \, a^{2} m r^{2} - i \, m r^{4} + {\left(i \, a^{4} m + i \, a^{2} m r^{2}\right)} \cos\left({\theta}\right)^{2}\right)} \sqrt{\cos\left({\theta}\right) + 1} \sqrt{-\cos\left({\theta}\right) + 1}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\theta}\wedge \mathrm{d} {\phi}$$

Let us check that $\mathcal{F}$ is self-dual, i.e. that it obeys ${}^* \mathcal{F} = -i \mathcal{F}$:

FF.hodge_dual(g) == - I * FF

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

Let us form the right self-dual of the Weyl tensor as follows $$\mathcal{C}_{\alpha\beta\mu\nu} = C_{\alpha\beta\mu\nu} + \frac{i}{2} \epsilon^{\rho\sigma}_{\ \ \ \mu\nu} \, C_{\alpha\beta\rho\sigma},$$ where $\epsilon^{\rho\sigma}_{\ \ \ \mu\nu}$ is associated to the Levi-Civita tensor $\epsilon_{\rho\sigma\mu\nu}$ and is obtained by

eps = g.volume_form(2)  # 2 = the first 2 indices are contravariant
print(eps)
eps.symmetries()

Tensor field of type (2,2) on the 4-dimensional Lorentzian manifold M
no symmetry; antisymmetries: [(0, 1), (2, 3)]

The right self-dual Weyl tensor is then

CC = Cd + I/2*( eps['^rs_..']*Cd['_..rs'] )
CC.set_name('CC', r'\mathcal{C}') ; print(CC)

Tensor field CC of type (0,4) on the 4-dimensional Lorentzian manifold M

CC.symmetries()

no symmetry; antisymmetries: [(0, 1), (2, 3)]

CC[0,1,2,3]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{{\left(3 i \, a^{4} m r \cos\left({\theta}\right)^{4} + 3 i \, a^{2} m r^{3} + 2 i \, m r^{5} + {\left(-9 i \, a^{4} m r - 7 i \, a^{2} m r^{3}\right)} \cos\left({\theta}\right)^{2}\right)} \sqrt{\cos\left({\theta}\right) + 1} \sqrt{-\cos\left({\theta}\right) + 1} + {\left(a^{5} m \cos\left({\theta}\right)^{5} - {\left(3 \, a^{5} m + 5 \, a^{3} m r^{2}\right)} \cos\left({\theta}\right)^{3} + 3 \, {\left(3 \, a^{3} m r^{2} + 2 \, a m r^{4}\right)} \cos\left({\theta}\right)\right)} \sin\left({\theta}\right)}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}}$$

The Ernst 1-form $\sigma_\alpha = 2 \mathcal{F}_{\mu\alpha} \, \xi^\mu$ (0 = contraction on the first index of $\mathcal{F}$):

sigma = 2*FF.contract(0, xi)

Instead of invoking the function contract(), we could have used the index notation to denote the contraction:

sigma == 2*( FF['_ma']*xi['^m'] )

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

sigma.set_name('sigma', r'\sigma') ; print(sigma)
sigma.display()

1-form sigma on the 4-dimensional Lorentzian manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\sigma = -\frac{2 \, {\left(2 i \, a m r \sqrt{\cos\left({\theta}\right) + 1} \sqrt{-\cos\left({\theta}\right) + 1} \cos\left({\theta}\right) + {\left(a^{2} m \cos\left({\theta}\right)^{2} - m r^{2}\right)} \sin\left({\theta}\right)\right)}}{{\left(a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}\right)} \sin\left({\theta}\right)} \mathrm{d} r + \left( -\frac{4 \, a^{2} m r \cos\left({\theta}\right) \sin\left({\theta}\right) - {\left(2 i \, a^{3} m \cos\left({\theta}\right)^{2} - 2 i \, a m r^{2}\right)} \sqrt{\cos\left({\theta}\right) + 1} \sqrt{-\cos\left({\theta}\right) + 1}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\theta}$$

The symmetric bilinear form $\gamma = \lambda \, g + \underline{\xi}\otimes\underline{\xi}$:

gamma = lamb*g + xi_form * xi_form
gamma.set_name('gamma', r'\gamma') ; print(gamma)
gamma.display()

Field of symmetric bilinear forms gamma on the 4-dimensional Lorentzian manifold M

$$\newcommand{\Bold}[1]{\mathbf{#1}}\gamma = \left( \frac{a^{2} \cos\left({\theta}\right)^{2} - 2 \, m r + r^{2}}{a^{2} - 2 \, m r + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( a^{2} \cos\left({\theta}\right)^{2} - 2 \, m r + r^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( \frac{2 \, a^{2} m r \sin\left({\theta}\right)^{4} - {\left(2 \, a^{2} m r - a^{2} r^{2} + 2 \, m r^{3} - r^{4} - {\left(a^{4} + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$$

Final computation leading to the Simon-Mars tensor:

First we evaluate $$ S^{(1)}_{\alpha\beta\gamma} = 4 \mathcal{C}_{\mu\alpha\nu\beta} \, \xi^\mu \, \xi^\nu \, \sigma_\gamma $$

S1 = 4*( CC.contract(0,xi).contract(1,xi) ) * sigma
print(S1)

Tensor field of type (0,3) on the 4-dimensional Lorentzian manifold M

Then we form the tensor $$ S^{(2)}_{\alpha\beta\gamma} = - \gamma_{\alpha\beta} \, \mathcal{C}_{\rho\gamma\mu\nu} \, \xi^\rho \, \mathcal{F}^{\mu\nu} $$ by first computing $\mathcal{C}_{\rho\gamma\mu\nu} \, \xi^\rho$:

xiCC = CC['_.r..']*xi['^r']
print(xiCC)

Tensor field of type (0,3) on the 4-dimensional Lorentzian manifold M

We use the index notation to perform the double contraction $\mathcal{C}_{\gamma\rho\mu\nu} \mathcal{F}^{\mu\nu}$:

FFuu = FF.up(g)

S2 = gamma * ( xiCC['_.mn']*FFuu['^mn'] )
print(S2)
S2.symmetries()

Tensor field of type (0,3) on the 4-dimensional Lorentzian manifold M
symmetry: (0, 1); no antisymmetry

The Simon-Mars tensor with respect to $\xi$ is obtained by antisymmetrizing $S^{(1)}$ and $S^{(2)}$ on their last two indices and adding them: $$ S_{\alpha\beta\gamma} = S^{(1)}_{\alpha[\beta\gamma]} + S^{(2)}_{\alpha[\beta\gamma]} $$ We use the index notation for the antisymmetrization:

S1A = S1['_a[bc]']
S2A = S2['_a[bc]']

An equivalent writing would have been (the last two indices being in position 1 and 2):

# S1A = S1.antisymmetrize(1,2)
# S2A = S2.antisymmetrize(1,2)

The Simon-Mars tensor is

S = S1A + S2A
S.set_name('S') ; print(S)
S.symmetries()

Tensor field S of type (0,3) on the 4-dimensional Lorentzian manifold M
no symmetry; antisymmetry: (1, 2)

S.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}S = 0$$

We thus recover the fact that the Simon-Mars tensor vanishes identically in Kerr spacetime.

To check that the above computation was not trival, here is the component 112=$rr\theta$ for each of the two parts of the Simon-Mars tensor:

S1A[1,1,2]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{8 \, a^{8} m^{2} \cos\left({\theta}\right)^{9} - 8 \, {\left(a^{8} m^{2} + 2 \, a^{6} m^{3} r + 9 \, a^{6} m^{2} r^{2}\right)} \cos\left({\theta}\right)^{7} + 8 \, {\left(2 \, a^{6} m^{3} r + 9 \, a^{6} m^{2} r^{2} + 20 \, a^{4} m^{3} r^{3} - 5 \, a^{4} m^{2} r^{4}\right)} \cos\left({\theta}\right)^{5} - 40 \, {\left(4 \, a^{4} m^{3} r^{3} - a^{4} m^{2} r^{4} + 2 \, a^{2} m^{3} r^{5} - a^{2} m^{2} r^{6}\right)} \cos\left({\theta}\right)^{3} - {\left(40 i \, a^{7} m^{2} r \cos\left({\theta}\right)^{6} - 16 i \, a m^{3} r^{6} + 8 i \, a m^{2} r^{7} + {\left(-80 i \, a^{5} m^{3} r^{2} - 40 i \, a^{5} m^{2} r^{3}\right)} \cos\left({\theta}\right)^{4} + {\left(160 i \, a^{3} m^{3} r^{4} - 72 i \, a^{3} m^{2} r^{5}\right)} \cos\left({\theta}\right)^{2}\right)} \sqrt{\cos\left({\theta}\right) + 1} \sqrt{-\cos\left({\theta}\right) + 1} \sin\left({\theta}\right) + 40 \, {\left(2 \, a^{2} m^{3} r^{5} - a^{2} m^{2} r^{6}\right)} \cos\left({\theta}\right)}{2 \, {\left(a^{2} r^{10} - 2 \, m r^{11} + r^{12} + {\left(a^{12} - 2 \, a^{10} m r + a^{10} r^{2}\right)} \cos\left({\theta}\right)^{10} + 5 \, {\left(a^{10} r^{2} - 2 \, a^{8} m r^{3} + a^{8} r^{4}\right)} \cos\left({\theta}\right)^{8} + 10 \, {\left(a^{8} r^{4} - 2 \, a^{6} m r^{5} + a^{6} r^{6}\right)} \cos\left({\theta}\right)^{6} + 10 \, {\left(a^{6} r^{6} - 2 \, a^{4} m r^{7} + a^{4} r^{8}\right)} \cos\left({\theta}\right)^{4} + 5 \, {\left(a^{4} r^{8} - 2 \, a^{2} m r^{9} + a^{2} r^{10}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)}$$

S2A[1,1,2]

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{8 \, a^{8} m^{2} \cos\left({\theta}\right)^{9} - 8 \, {\left(a^{8} m^{2} + 2 \, a^{6} m^{3} r + 9 \, a^{6} m^{2} r^{2}\right)} \cos\left({\theta}\right)^{7} + 8 \, {\left(2 \, a^{6} m^{3} r + 9 \, a^{6} m^{2} r^{2} + 20 \, a^{4} m^{3} r^{3} - 5 \, a^{4} m^{2} r^{4}\right)} \cos\left({\theta}\right)^{5} - 40 \, {\left(4 \, a^{4} m^{3} r^{3} - a^{4} m^{2} r^{4} + 2 \, a^{2} m^{3} r^{5} - a^{2} m^{2} r^{6}\right)} \cos\left({\theta}\right)^{3} - {\left(40 i \, a^{7} m^{2} r \cos\left({\theta}\right)^{6} - 16 i \, a m^{3} r^{6} + 8 i \, a m^{2} r^{7} + {\left(-80 i \, a^{5} m^{3} r^{2} - 40 i \, a^{5} m^{2} r^{3}\right)} \cos\left({\theta}\right)^{4} + {\left(160 i \, a^{3} m^{3} r^{4} - 72 i \, a^{3} m^{2} r^{5}\right)} \cos\left({\theta}\right)^{2}\right)} \sqrt{\cos\left({\theta}\right) + 1} \sqrt{-\cos\left({\theta}\right) + 1} \sin\left({\theta}\right) + 40 \, {\left(2 \, a^{2} m^{3} r^{5} - a^{2} m^{2} r^{6}\right)} \cos\left({\theta}\right)}{2 \, {\left(a^{2} r^{10} - 2 \, m r^{11} + r^{12} + {\left(a^{12} - 2 \, a^{10} m r + a^{10} r^{2}\right)} \cos\left({\theta}\right)^{10} + 5 \, {\left(a^{10} r^{2} - 2 \, a^{8} m r^{3} + a^{8} r^{4}\right)} \cos\left({\theta}\right)^{8} + 10 \, {\left(a^{8} r^{4} - 2 \, a^{6} m r^{5} + a^{6} r^{6}\right)} \cos\left({\theta}\right)^{6} + 10 \, {\left(a^{6} r^{6} - 2 \, a^{4} m r^{7} + a^{4} r^{8}\right)} \cos\left({\theta}\right)^{4} + 5 \, {\left(a^{4} r^{8} - 2 \, a^{2} m r^{9} + a^{2} r^{10}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)}$$

S1A[1,1,2] + S2A[1,1,2]

$$\newcommand{\Bold}[1]{\mathbf{#1}}0$$