This notebook shows how to use SageMath to compute the Christoffel symbols of standard coordinates in Schwarzschild spacetime, as well as the Riemann curvature tensor and the Kretschmann scalar. The corresponding tools have been developed within the SageManifolds project (version 1.2, as included in SageMath 8.2).
A more advanced notebook about Schwarzschild spacetime, involving many coordinate charts, more tensor calculus and graphical outputs, is available here.
Click here to download the notebook file (ipynb format). To run it, you must start SageMath with the Jupyter interface, via the command sage -n jupyter
NB: a version of SageMath at least equal to 8.2 is required to run this worksheet:
version()
'SageMath version 8.2, Release Date: 2018-05-05'
First we set up the notebook to display mathematical objects via LaTeX rendering:
%display latex
We declare the spacetime manifold as a 4-dimensional Lorentzian manifold:
M = Manifold(4, 'M', structure='Lorentzian')
print(M)
4-dimensional Lorentzian manifold M
The standard Schwarzschild-Droste coordinates are introduced via the method chart()
applied to the manifold object M
. Note that the argument of chart()
is a raw string (hence the prefix r
in front of it), which
defines the range of each coordinate, if different from $(-\infty, +\infty)$, as well as its LaTeX symbol, if different from the Python symbol to denote the coordinate. The Python variables for each coordinate are declared within the <...>
operator on the left-hand side, X
denoting the Python variable chosen for the coordinate chart.
X.<t,r,th,ph> = M.chart(r"t r:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\phi")
X
X[:]
X[0], X[3]
We introduce first the mass parameter $m$ as a symbolic variable, via the function var()
:
m = var('m')
assume(m>=0)
The metric tensor of the Lorentzian manifold M
is returned by the method metric()
; we initialize its components in the chart X
, which is the default (unique) chart on M
:
g = M.metric()
g[0,0] = -(1-2*m/r)
g[1,1] = 1/(1-2*m/r)
g[2,2] = r^2
g[3,3] = (r*sin(th))^2
g.display()
Viewing the metric components as a matrix:
g[:]
Accessing to a specific component:
g[0,0]
The Christoffel symbols of $g$ with respect to the Schwarzschild-Droste coordinates are
printed by the method christoffel_symbols_display()
applied to the metric object g
. By
default, only the nonzero symbols and the nonredundant ones (taking into account the symmetry of the last two indices) are displayed. Type g.christoffel_symbols_display?
to see all possible options.
g.christoffel_symbols_display()
Accessing to a Christoffel symbol specified by its indices:
g.christoffel_symbols()[0,0,1]
Checking the symmetry on the last two indices:
g.christoffel_symbols()[0,0,1] == g.christoffel_symbols()[0,1,0]
Let us check that $g$ is a solution of the vacuum Einstein equation, i.e. that its Ricci tensor vanishes identically:
g.ricci()
g.ricci().display()
g.ricci()[:]
The Riemann curvature tensor is obtained by the method riemann()
:
R = g.riemann()
print(R)
Tensor field Riem(g) of type (1,3) on the 4-dimensional Lorentzian manifold M
Contrary to the Ricci tensor, it is not identically zero:
R.display()
The component $R^0_{\ \,101} = R^t_{\ \,trt}$ of the Riemann tensor:
R[0,1,0,1]
The Kretschmann scalar is the "square" of the Riemann tensor defined by
$$ K = R_{abcd} R^{abcd}$$
To compute it, we must form first the tensor fields whose components are $R_{abcd}$ and
$R^{abcd}$. They are obtained by respectively lowering and raising the indices of the components $R^a_{\ \, bcd}$ of the Riemann tensor, via the metric $g$. These two operations are performed by the methods down()
and up()
. The contraction is performed by summation on repeated indices, using LaTeX notations:
K = R.down(g)['_{abcd}'] * R.up(g)['^{abcd}']
K
K.display()
The symbolic expression representing the scalar field $K$ is returned by the method expr()
:
K.expr()