Defining a degenerate metric manifold $M$

This Jupyter notebook illustrates SageMath functionalities regarding smooth manifolds equipped with a degenerate metric. The involved tools have been developed through the SageManifolds project.

Author: Hans Fotsing Tetsing

A version of SageMath at least equal to 9.1 is required to run this notebook

version()

'SageMath version 9.1, Release Date: 2020-05-20'

%display latex

M = Manifold(3, 'M', structure='degenerate_metric')
print(M)

3-dimensional degenerate_metric manifold M

We call $g$ the metric on $M$

g = M.metric() 
print(g)

degenerate metric g on the 3-dimensional degenerate_metric manifold M

g.parent()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathcal{T}^{(0,2)}\left(M\right)$$

det(g).display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} 0:& M & \longrightarrow & \mathbb{R} \end{array}$$

The determinant of any degenerate matric is the zero scalar function. By default (when the components are not yet set) the signature is the triplet (n_-,n_+,n_0) where n_-=0 is the number of negative entries, n_+=dim(M) the number of positive entries and n_0=1 is the number number of zero in the digonal, all that in the writting of the metric in an orthogonal basis.

g.signature()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(0, 2, 1\right)$$

U = M.open_subset('U')
print(U)

Open subset U of the 3-dimensional degenerate_metric manifold M

X.<x,y,z> = U.chart(); X

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(U,(x, y, z)\right)$$

One can use a field of symmetric bilinear forms to set the components of a degenerate metric.

dx, dy = X.coframe()[0], X.coframe()[1]

b = dx*dx + x^2*dy*dy
b = b.symmetrize()
print(b)

Field of symmetric bilinear forms on the Open subset U of the 3-dimensional degenerate_metric manifold M

g.set(b)

g.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}g = \mathrm{d} x\otimes \mathrm{d} x + x^{2} \mathrm{d} y\otimes \mathrm{d} y$$

g[:]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrr} 1 & 0 & 0 \\ 0 & x^{2} & 0 \\ 0 & 0 & 0 \end{array}\right)$$

We define another metric and set its nonzero components.

h = g._new_instance()
h.set_name('h')
print(h)

degenerate metric h on the 3-dimensional degenerate_metric manifold M

h[0,0], h[1,1] = 1, x^2

h.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}h = \mathrm{d} x\otimes \mathrm{d} x + x^{2} \mathrm{d} y\otimes \mathrm{d} y$$

On the only local chart (U,X), h and g have the same components, so there are equal! However, g is the metric of the degenerate metric manifold M but not h.

h == g

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

g is M.metric()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

h is M.metric()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{False}$$

Degenerate hypersurface of a 6-dimensional Lorentzian manifold

M = Manifold(6, 'M', structure='Lorentzian')
print(M)

6-dimensional Lorentzian manifold M

X.<x0,x1,x2,x3,x4,x5> = M.chart(); X

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(M,(x_{0}, x_{1}, x_{2}, x_{3}, x_{4}, x_{5})\right)$$

g = M.metric()
print(g)

Lorentzian metric g on the 6-dimensional Lorentzian manifold M

g[0,0], g[1,1], g[2,2], g[3,3], g[4,4], g[5,5] = -1, 1, exp(2*x0), exp(2*x0), exp(2*x1), exp(2*x1)

g[:]

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrrrr} -1 & 0 & 0 & 0 & 0 & 0 \\ 0 & 1 & 0 & 0 & 0 & 0 \\ 0 & 0 & e^{\left(2 \, x_{0}\right)} & 0 & 0 & 0 \\ 0 & 0 & 0 & e^{\left(2 \, x_{0}\right)} & 0 & 0 \\ 0 & 0 & 0 & 0 & e^{\left(2 \, x_{1}\right)} & 0 \\ 0 & 0 & 0 & 0 & 0 & e^{\left(2 \, x_{1}\right)} \end{array}\right)$$

We define now on M the degenerate hypersurface x0+x1=0.

H = Manifold(5, 'H', ambient=M, structure='degenerate_metric')
print(H)

degenerate hypersurface H embedded in 6-dimensional differentiable manifold M

X_H.<xh1, xh2, xh3, xh4, xh5> = H.chart(); X_H

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(H,(\mathit{xh}_{1}, \mathit{xh}_{2}, \mathit{xh}_{3}, \mathit{xh}_{4}, \mathit{xh}_{5})\right)$$

Phi = H.diff_map(M, {(X_H, X): [-xh1, xh1, xh2, xh3, xh4, xh5]}, 
                 name='Phi', latex_name=r'\Phi')
Phi.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} \Phi:& H & \longrightarrow & M \\ & \left(\mathit{xh}_{1}, \mathit{xh}_{2}, \mathit{xh}_{3}, \mathit{xh}_{4}, \mathit{xh}_{5}\right) & \longmapsto & \left(x_{0}, x_{1}, x_{2}, x_{3}, x_{4}, x_{5}\right) = \left(-\mathit{xh}_{1}, \mathit{xh}_{1}, \mathit{xh}_{2}, \mathit{xh}_{3}, \mathit{xh}_{4}, \mathit{xh}_{5}\right) \end{array}$$

Phi_inv = M.diff_map(H, {(X, X_H): [x1, x2, x3, x4, x5]}, 
                     name='Phi_inv', latex_name=r'\Phi^{-1}')
Phi_inv.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} \Phi^{-1}:& M & \longrightarrow & H \\ & \left(x_{0}, x_{1}, x_{2}, x_{3}, x_{4}, x_{5}\right) & \longmapsto & \left(\mathit{xh}_{1}, \mathit{xh}_{2}, \mathit{xh}_{3}, \mathit{xh}_{4}, \mathit{xh}_{5}\right) = \left(x_{1}, x_{2}, x_{3}, x_{4}, x_{5}\right) \end{array}$$

H.set_immersion(Phi, inverse=Phi_inv)
H.declare_embedding()

The vector field $v=-\partial x0-\partial x1$ is everywhere neither orthogonal nor tangent to $H$. Hence, $v$ is a rigging for the null hypersurface $H$.

v = M.vector_field()
v[:2] = [-1, -1]
v.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{\partial}{\partial x_{0} }-\frac{\partial}{\partial x_{1} }$$

H.set_transverse(rigging=[v])

The vector $\xi=\partial x0-\partial x1$ is tangent and orthogonal to $H$ and then spans the normal distribution $TH^\perp$. A complementary of $TH^\perp$ in $TH$, thus a screen distribution, is spanned by the vectors $e1=\exp(-2x0)\partial x2$, $e2=\exp(-2x0)\partial x3$, $e3=\exp(-2x1)\partial x4$, and $e4=\exp(-2x1)\partial x5$. Notice that the screen distribution associated with $v$ has to be othogonal to the chosen rigging $v$.

xi = M.vector_field()
e1 = M.vector_field()
e2 = M.vector_field()
e3 = M.vector_field()
e4 = M.vector_field()

xi[:2] = [1, -1]
e1[2] = exp(-2*x0)
e2[3] = exp(-2*x0)
e3[4] = exp(-2*x1)
e4[5] = exp(-2*x1)

S = H.screen('S', [e1, e2, e3, e4], [xi])
print(S)

screen distribution S along the degenerate hypersurface H embedded in 6-dimensional differentiable manifold M mapped into the 6-dimensional Lorentzian manifold M

H.default_screen()

$$\newcommand{\Bold}[1]{\mathbf{#1}}S$$

The null rigging is derived from the given rigging $v$ with the formula$$N=\frac{1}{g(\xi, v)}\left(v-\frac{g(v,v)}{2g(\xi, v)}\xi\right)$$ Projections onto $H$ will be done parallely to the null rigging $N$.

S.rigging().display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}N = -\frac{1}{2} \frac{\partial}{\partial x_{0} } -\frac{1}{2} \frac{\partial}{\partial x_{1} }$$

S.normal_tangent_vector().display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\xi = \frac{\partial}{\partial x_{0} }-\frac{\partial}{\partial x_{1} }$$

The null rigging $N$ and the normal tangent vector $\xi$ are normalized by$$g(N,\xi)=1.$$ This normalization is the one used by some mathematicians but is not physically relevant since $N$ and $\xi$ cannot be timelike at the same time. However, one can consider $\ell=\xi$ and $k=-N$.

g.along(Phi)(S.rigging(),xi.along(Phi)).display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & H & \longrightarrow & \mathbb{R} \\ & \left(\mathit{xh}_{1}, \mathit{xh}_{2}, \mathit{xh}_{3}, \mathit{xh}_{4}, \mathit{xh}_{5}\right) & \longmapsto & 1 \end{array}$$

Now, $S$ is a screen distribution along $H$ and we have the decompositions \begin{equation}TM|_H=TH\oplus Span(N)\end{equation} \begin{equation}TH=S\oplus_{orth}Span(\xi)\end{equation} Projection on $H$ is done with respect to the first decomposition and projection onto the screen distribution of a vector tangent to $H$ is done with respect to the second decomposition. So, any vector along $H$ (tangent or not to $H$), can be decomposed in the adapted frame $T=\{vv_0,vv_1,vv_2,vv_3,vv_4,vv_5)$, where along $H$ $$vv_0:=e1,~~vv_1=e2,~~vv_2=e3,~~vv_3=e4,~~vv_4=\xi,~~vv_5=N.$$

T = H.adapted_frame()
T

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(H, \left(vv_{0},vv_{1},vv_{2},vv_{3},vv_{4},vv_{5}\right)\right)$$

T[4].display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\xi = \frac{\partial}{\partial x_{0} }-\frac{\partial}{\partial x_{1} }$$

T[0].disp()

$$\newcommand{\Bold}[1]{\mathbf{#1}}vv_{0} = e^{\left(2 \, \mathit{xh}_{1}\right)} \frac{\partial}{\partial x_{2} }$$

Projections on $H$ and on the screen distribution are now possible!

H.projection(v).display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}0$$

H.projection(v+xi).display(T)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\xi$$

H.screen_projection(v+xi).display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}0$$

H.screen_projection(e1+xi).display(T)

$$\newcommand{\Bold}[1]{\mathbf{#1}}vv_{0}$$

Let $\nabla$ be the Levi-Civita connection of $(M,g)$. The Weingarten map is the projection is $\nabla_\cdot\xi:\mathfrak X(H)\to\mathfrak X(H)$.

W = H.weingarten_map()
print(W)

Tensor field nabla_g(xi)|X(H) of type (1,1) along the degenerate hypersurface H embedded in 6-dimensional differentiable manifold M with values on the 6-dimensional Lorentzian manifold M

W.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\nabla_g(\xi)|_{\mathfrak{X}(H)} = \frac{\partial}{\partial x_{2} }\otimes \mathrm{d} x_{2}+\frac{\partial}{\partial x_{3} }\otimes \mathrm{d} x_{3}-\frac{\partial}{\partial x_{4} }\otimes \mathrm{d} x_{4}-\frac{\partial}{\partial x_{5} }\otimes \mathrm{d} x_{5}$$

W.display(T)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\nabla_g(\xi)|_{\mathfrak{X}(H)} = vv_{0}\otimes vv^{0}+vv_{1}\otimes vv^{1}-vv_{2}\otimes vv^{2}-vv_{3}\otimes vv^{3}$$

W(xi.along(Phi)).display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}0$$

W(T[0]).display(T)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\nabla_g(\xi)|_{\mathfrak{X}(H)}\left(vv_{0}\right) = vv_{0}$$

We can write$$\nabla_U\xi=-A^\ast(U)-\tau(U)\xi,~~~~\forall U\in\mathfrak X(H).$$ $A^\ast$ is the shape operator and $\tau$ the roration $1-$form.

SO = H.shape_operator()
print(SO)

Tensor field A^* of type (1,1) along the degenerate hypersurface H embedded in 6-dimensional differentiable manifold M with values on the 6-dimensional Lorentzian manifold M

SO.display(T)

$$\newcommand{\Bold}[1]{\mathbf{#1}}A^\ast = -vv_{0}\otimes vv^{0}-vv_{1}\otimes vv^{1}+vv_{2}\otimes vv^{2}+vv_{3}\otimes vv^{3}$$

The principal curvatures are the eigenfunctions of the shape operator.

m = H.mean_curvature()
m.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & H & \longrightarrow & \mathbb{R} \\ & \left(\mathit{xh}_{1}, \mathit{xh}_{2}, \mathit{xh}_{3}, \mathit{xh}_{4}, \mathit{xh}_{5}\right) & \longmapsto & 0 \end{array}$$

So, the mean curvature of $H$ vanishes identically. Some people then say that $H$ is a maximal null hypersurface. But, $H$ is not totally geodesic since the shape operator is not zero. Hence, the ambient manifold $(M,g)$ cannot have constant sectional curvature.

In fact, the principal curvatures are $-1,-1,0,1,1$ and we can write the following short code to get them.

curvatures = matrix([[SO[:][i, j].expr() for i in H.irange()]
                     for j in H.irange()]).eigenvalues()
counter = H.irange()
for i in range(5):
    curvatures[i] = H.scalar_field(curvatures[i], name="k_{}".format(next(counter)))

curvatures[0].display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} k_0:& H & \longrightarrow & \mathbb{R} \\ & \left(\mathit{xh}_{1}, \mathit{xh}_{2}, \mathit{xh}_{3}, \mathit{xh}_{4}, \mathit{xh}_{5}\right) & \longmapsto & -1 \end{array}$$

The principal directions are $vv_0,vv_1,vv_2,vv_3=\xi$.

PD = H.principal_directions(S)
PD[0][0].disp(T), PD[1][0].disp(T), PD[2][0].disp(T), PD[3][0].disp(T)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(e_0 = vv_{0}, e_1 = vv_{1}, e_2 = \xi, e_3 = vv_{2}\right)$$

Defining a second screen distribution

Since the screen distribution has to be orthogonal to the rigging, the screen distribution is unique ones the rigging has been set. One can just change the basis but the result is the same subbundle.

u1 = M.vector_field()
u2 = M.vector_field()
u3 = M.vector_field()
u4 = M.vector_field()

u1[2] = 1; u2[3] = 1; u3[4] = 1; u4[5] = 1

S1 = H.screen('S1', [u1, u2, u3, u4], [xi])
print(S1)

screen distribution S1 along the degenerate hypersurface H embedded in 6-dimensional differentiable manifold M mapped into the 6-dimensional Lorentzian manifold M

The default screen distribution is always the last defined one.

H.default_screen()

$$\newcommand{\Bold}[1]{\mathbf{#1}}S1$$

T1 = H.adapted_frame(screen=S1)
T1

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(H, \left(vv1_{0},vv1_{1},vv1_{2},vv1_{3},vv1_{4},vv1_{5}\right)\right)$$

T1[4].display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\xi = \frac{\partial}{\partial x_{0} }-\frac{\partial}{\partial x_{1} }$$

T1[0].display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}vv1_{0} = \frac{\partial}{\partial x_{2} }$$

SO1 = H.shape_operator(S1)
print(SO1)

Tensor field A^* of type (1,1) along the degenerate hypersurface H embedded in 6-dimensional differentiable manifold M with values on the 6-dimensional Lorentzian manifold M

SO1.display(T1)

$$\newcommand{\Bold}[1]{\mathbf{#1}}A^\ast = -vv1_{0}\otimes vv1^{0}-vv1_{1}\otimes vv1^{1}+vv1_{2}\otimes vv1^{2}+vv1_{3}\otimes vv1^{3}$$

SO == SO1

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}$$

Let's now define a new rigging and from that a different screen distribution.

v2 = M.vector_field()
v2[1:3] = [1,1]
v2.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{\partial}{\partial x_{1} }+\frac{\partial}{\partial x_{2} }$$

H.set_transverse(rigging=[v2])

e21 = M.vector_field()
e22 = M.vector_field()
e23 = M.vector_field()
e24 = M.vector_field()

e21[0:3] = [1,-1,exp(-2*x0)]
e22[3] = 1
e23[4] = 1
e24[5] = 1

S2 = H.screen('S2', [e21, e22, e23, e24], [xi])
print(S2)

screen distribution S2 along the degenerate hypersurface H embedded in 6-dimensional differentiable manifold M mapped into the 6-dimensional Lorentzian manifold M

T2 = H.adapted_frame(screen=S2)
T2

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(H, \left(vv2_{0},vv2_{1},vv2_{2},vv2_{3},vv2_{4},vv2_{5}\right)\right)$$

SO2 = H.shape_operator(S2)
SO2.display(T2)

SO == SO2

This is because the shape operator depends on the chosen rigging.

H.list_of_screens()

W2 = H.weingarten_map(S2)
W2.display(T2)

W2(xi.along(Phi)).display()

The Weingarten map can only be applied to vectors tangent to $H$. However, we can consider its extension which can evaluate any vector along $H$ (tangent to $H$ or not).

W2.extension()(v2.along(Phi)).display(T2)

W.extension() == W2.extension()