Notebook

SageMath físicos¶

Rogério T. C.

SageMath (ou simplesmente Sage) é um sistema de computação algébrica. Dentre outras, algumas vantágens de usar sistemas desse tipo são:

Você pode se concentrar mais nas idéias (modelo, formulação, teoria) e menos nas "contas";

Os resultados estendidos, generalizados e analisados com facilidade;

Você pode explorar a estrutura matemática em torno do seu problema, o Sage é ótimo para isso;

Seus resultados podem ser compartilhados de uma forma reproduzível;

Depois de investir algum tempo aprendendo o básico, você poderá resolver problema de forma muito mais rápido e com mais ferramentas;

Você só precisa saber um conjunto básico de comandos e sintaxe, e para todo o restante pode usar os recursos de ajuda e a documentação;

Tópicos da aula de hoje

Pré-documento;
Operações básicas;
Variáveis simbólicas;
Expressões simbólicas;
Equações, inequações e sistemas
Ferramentas de cálculo
Substituições em expressões simbólicas
Equações diferenciais ordinárias

Aula I¶

1. Pré-documento¶

Você pode fazer o jupyter exibir as equações no formato $\LaTeX{}$ digitando %display latex em uma célula.

In [1]:

%display latex # outras opções são plane, ascii_art e unicode_art

In [2]:

reset() #inicializa todas as variáveis

2. Operações Básicas¶

No Sage as operações básicas com números reais, complexos, racionais, etc., são realizadas como nas calculadoras científicas. Frações e raízes são automaticamente simplificadas

In [3]:

15/25+3/2

Out[3]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{21}{10}$

In [4]:

sqrt(20)/pi

Out[4]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{2 \, \sqrt{5}}{\pi}$

Aproximação numérica

In [5]:

sqrt(20).n()

Out[5]:

$\newcommand{\Bold}[1]{\mathbf{#1}}4.47213595499958$

In [6]:

sqrt(20.0)

Out[6]:

$\newcommand{\Bold}[1]{\mathbf{#1}}4.47213595499958$

Algumas operações e funções básicas do Sage:

Operação	Sintáxe
4 operações	`a+b, a-b, a*b, a/b`
Potêmcia	`a**b ou a^b`
Raiz quadrada	`sqrt(a)`
Divisão inteira	`a//b`
Resto na divisão	`a%b`
Fatorial	`factorial(a)`
Coeficiente binômial $\begin{pmatrix} a\\ b\end{pmatrix}$	`binomial(a,b)`
Parte inteira	`floor(a)`
Valor absoluto	`abs(a)`
Aproximação numérica	`N(a) ou a.n()`

3. Variáveis simbólicas¶

Existem dois tipos básicos de variáveis no sage:

As variáveis simbólicas, usadas nos cálculos simbólicos;

Variáveis python, que são usadas para guardas alguma informação na memória.

Variáveis simbólicas precisam ser declaradas. Exceto x, que já vem pré-declarada.

In [7]:

var('u y w a b c') 

Out[7]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(u, y, w, a, b, c\right)$

Uma lista de varáveis simbólicas indexadas pode ser criada com:

In [8]:

X = var('x',n=4)
X

Out[8]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(x_{0}, x_{1}, x_{2}, x_{3}\right)$

In [9]:

X[1]

Out[9]:

$\newcommand{\Bold}[1]{\mathbf{#1}}x_{1}$

Você pode tammbém definir o domínio e um nome $\LaTeX{}$ para variáveis simbólicas.

In [10]:

var('alp_bar', latex_name=r'\bar{\alpha}', domain='real')

Out[10]:

$\newcommand{\Bold}[1]{\mathbf{#1}}{\bar{\alpha}}$

In [11]:

alp_bar

Out[11]:

$\newcommand{\Bold}[1]{\mathbf{#1}}{\bar{\alpha}}$

Variáveis simbólicas são usadas, por exemplo, para declarar funções.

In [12]:

f(u)=cos(u)^6 + sin(u)^6 + 3 * sin(u)^2 * cos(u)^2
f

Out[12]:

$\newcommand{\Bold}[1]{\mathbf{#1}}u \ {\mapsto}\ \cos\left(u\right)^{6} + \sin\left(u\right)^{6} + 3 \, \cos\left(u\right)^{2} \sin\left(u\right)^{2}$

Código $\LaTeX$

In [13]:

print(latex(f(u)))

\cos\left(u\right)^{6} + \sin\left(u\right)^{6} + 3 \, \cos\left(u\right)^{2} \sin\left(u\right)^{2}

Assim como Python, o Sage usa o paradigma de orientação ao objeto. Se você digitar . após o nome de um objeto e apertar a tecla Tab, será exibda uma lista de métodos associados a este objeto.

In [ ]:

A última saída é armazenada na variável _
Penúltima em __
Antepenúltima ___

In [14]:

Out[14]:

$\newcommand{\Bold}[1]{\mathbf{#1}}u \ {\mapsto}\ \cos\left(u\right)^{6} + \sin\left(u\right)^{6} + 3 \, \cos\left(u\right)^{2} \sin\left(u\right)^{2}$

Um ? após o nome de uma função exibe uma descrição da mesma, geralmente com alguns exemplos.

In [ ]:

4. Expressões simbólicas¶

Expressões simbólicas podem ser manipuladas de várias formas

In [16]:

p = (x+y)*(x+1)^2; p

Out[16]:

$\newcommand{\Bold}[1]{\mathbf{#1}}{\left(x + y\right)} {\left(x + 1\right)}^{2}$

In [17]:

p2 = p.expand(); p2

Out[17]:

$\newcommand{\Bold}[1]{\mathbf{#1}}x^{3} + x^{2} y + 2 \, x^{2} + 2 \, x y + x + y$

In [18]:

p2.collect(x) #potências da x

Out[18]:

$\newcommand{\Bold}[1]{\mathbf{#1}}x^{3} + x^{2} {\left(y + 2\right)} + x {\left(2 \, y + 1\right)} + y$

In [19]:

p2.factor()

Out[19]:

$\newcommand{\Bold}[1]{\mathbf{#1}}{\left(x + y\right)} {\left(x + 1\right)}^{2}$

Identidades trigonômétricas podem ser utilizadas com .expand_trig()

In [20]:

sin(x+y).expand_trig()

Out[20]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\cos\left(y\right) \sin\left(x\right) + \cos\left(x\right) \sin\left(y\right)$

In [21]:

tanh(x+y).expand_trig()

Out[21]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{\tanh\left(x\right) + \tanh\left(y\right)}{\tanh\left(x\right) \tanh\left(y\right) + 1}$

Ou simplificadas usando trig_simplify()

In [22]:

f(u)

Out[22]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\cos\left(u\right)^{6} + \sin\left(u\right)^{6} + 3 \, \cos\left(u\right)^{2} \sin\left(u\right)^{2}$

In [23]:

f(u).diff()

Out[23]:

$\newcommand{\Bold}[1]{\mathbf{#1}}-6 \, \cos\left(u\right)^{5} \sin\left(u\right) + 6 \, \cos\left(u\right) \sin\left(u\right)^{5} + 6 \, \cos\left(u\right)^{3} \sin\left(u\right) - 6 \, \cos\left(u\right) \sin\left(u\right)^{3}$

In [24]:

f(u).trig_simplify()

Out[24]:

$\newcommand{\Bold}[1]{\mathbf{#1}}1$

In [25]:

f(u).diff().trig_simplify()

Out[25]:

$\newcommand{\Bold}[1]{\mathbf{#1}}0$

Manipulação simbólica de polinômios:

Função	Comando
expandir	`expand()`
polinômio em `x`	`collect(x)`
Fatorar	`factor()`

Funções trigonométricas:

Função	Comando
Simplificação	`trig_simplify()`
Linearização	`reduce_trig()`
Expansão	`expand_trig()`

Raízes e frações:

Função	Comando
Somar frações com o mesmo denominador	`combine()`
Rotina de simplificações com raízes e frações(muito útil)	`canonicalize_radical()`

Geral:

Função	Comando
Simplificação	`simplify()`
Simplificação completa	`full_simplify()`

5. Equações, inequações e sistemas¶

Equações podem ser definidas por expressões simbólicas e guardadas em variáveis python e manipuladas.

In [26]:

var('phi')
eq0 = y**2 - 2/cos(phi)*y + 5/cos(phi)**2 - 4 == 0; eq0

Out[26]:

$\newcommand{\Bold}[1]{\mathbf{#1}}y^{2} - \frac{2 \, y}{\cos\left(\phi\right)} + \frac{5}{\cos\left(\phi\right)^{2}} - 4 = 0$

Note que equações são definidas pelo operador `==`

In [27]:

eq1=(eq0*cos(phi)^2).expand(); eq1

Out[27]:

$\newcommand{\Bold}[1]{\mathbf{#1}}y^{2} \cos\left(\phi\right)^{2} - 2 \, y \cos\left(\phi\right) - 4 \, \cos\left(\phi\right)^{2} + 5 = 0$

Para extrair os lados da equação, .lhs() ou .rhs()

In [28]:

eq1.lhs()

Out[28]:

$\newcommand{\Bold}[1]{\mathbf{#1}}y^{2} \cos\left(\phi\right)^{2} - 2 \, y \cos\left(\phi\right) - 4 \, \cos\left(\phi\right)^{2} + 5$

In [29]:

eq1.rhs()

Out[29]:

$\newcommand{\Bold}[1]{\mathbf{#1}}0$

Equações também podem ser resolvidas diretamente usando o comando solve

In [30]:

solve(eq1,y)

Out[30]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[y = -\frac{2 \, \sqrt{\cos\left(\phi\right)^{2} - 1} - 1}{\cos\left(\phi\right)}, y = \frac{2 \, \sqrt{\cos\left(\phi\right)^{2} - 1} + 1}{\cos\left(\phi\right)}\right]$

In [31]:

sol=solve(eq1,phi); sol

Out[31]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\phi = \pi - \arccos\left(-\frac{y}{y^{2} - 4} + \frac{2 \, \sqrt{-y^{2} + 5}}{y^{2} - 4}\right), \phi = \arccos\left(\frac{y}{y^{2} - 4} + \frac{2 \, \sqrt{-y^{2} + 5}}{y^{2} - 4}\right)\right]$

In [32]:

sol[0]

Out[32]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\phi = \pi - \arccos\left(-\frac{y}{y^{2} - 4} + \frac{2 \, \sqrt{-y^{2} + 5}}{y^{2} - 4}\right)$

In [33]:

sol[0].rhs()

Out[33]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\pi - \arccos\left(-\frac{y}{y^{2} - 4} + \frac{2 \, \sqrt{-y^{2} + 5}}{y^{2} - 4}\right)$

In [34]:

print(latex(sol[0].rhs()))

\pi - \arccos\left(-\frac{y}{y^{2} - 4} + \frac{2 \, \sqrt{-y^{2} + 5}}{y^{2} - 4}\right)

Você pode assumir expressões simbólicas que serão usadas nos cálculos simbólicos internamente com a função assume(expressão)

In [35]:

assume(phi^2<20)

In [36]:

assumptions()

Out[36]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\verb|alp_bar|\phantom{\verb!x!}\verb|is|\phantom{\verb!x!}\verb|real|, \phi^{2} < 20\right]$

5.1 Sistemas de equações e inequações¶

O solve também resolve sistemas de equações ou inequações

In [37]:

eq2 = x^2 + x*y + 2 == 0
eq3 = y^2 == x*(x+y)
(eq2, eq3)

Out[37]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(x^{2} + x y + 2 = 0, y^{2} = {\left(x + y\right)} x\right)$

In [38]:

sols = solve((eq2, eq3), x, y)
sols

Out[38]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[x = -\frac{1}{2} i \, \sqrt{10} + \frac{1}{2} i \, \sqrt{2}, y = -i \, \sqrt{2}\right], \left[x = \frac{1}{2} i \, \sqrt{10} + \frac{1}{2} i \, \sqrt{2}, y = -i \, \sqrt{2}\right], \left[x = -\frac{1}{2} i \, \sqrt{10} - \frac{1}{2} i \, \sqrt{2}, y = i \, \sqrt{2}\right], \left[x = \frac{1}{2} i \, \sqrt{10} - \frac{1}{2} i \, \sqrt{2}, y = i \, \sqrt{2}\right]\right]$

In [39]:

sols[0]

Out[39]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[x = -\frac{1}{2} i \, \sqrt{10} + \frac{1}{2} i \, \sqrt{2}, y = -i \, \sqrt{2}\right]$

In [40]:

sols[0][0]

Out[40]:

$\newcommand{\Bold}[1]{\mathbf{#1}}x = -\frac{1}{2} i \, \sqrt{10} + \frac{1}{2} i \, \sqrt{2}$

In [41]:

solve(x^2+x-1 > 0, x)

Out[41]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[x < -\frac{1}{2} \, \sqrt{5} - \frac{1}{2}\right], \left[x > \frac{1}{2} \, \sqrt{5} - \frac{1}{2}\right]\right]$

5.2 Solução numérica¶

Em alguns casos o solve não consegue encontar uma solução para a equação.

In [42]:

expr = sin(x) + sin(2 * x) + sin(3 * x)==0;expr

Out[42]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\sin\left(3 \, x\right) + \sin\left(2 \, x\right) + \sin\left(x\right) = 0$

In [43]:

solve(expr, x)

Out[43]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\sin\left(3 \, x\right) = -\sin\left(2 \, x\right) - \sin\left(x\right)\right]$

Nesses casos podemos usar a função find_root

A função find_root(equação, min, max) procura solução numérica para a equação no intervalo entre min e max.

In [44]:

find_root(expr,.1,pi)

Out[44]:

$\newcommand{\Bold}[1]{\mathbf{#1}}2.0943951023931957$

Nesse caso particular, uma solução analítica poderia ser obtida simplificando a equação

In [45]:

expr2 = expr.simplify_trig().factor(); expr2

Out[45]:

$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left(2 \, \cos\left(x\right) + 1\right)} \cos\left(x\right) \sin\left(x\right) = 0$

In [46]:

solve(expr2, x)

Out[46]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left[x = 0, x = \frac{2}{3} \, \pi, x = \frac{1}{2} \, \pi\right]$

In [47]:

expr.lhs()

Out[47]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\sin\left(3 \, x\right) + \sin\left(2 \, x\right) + \sin\left(x\right)$

In [48]:

plot(expr.lhs(),(x,0,pi), gridlines=True)

Out[48]:

Note que existem mais sluções do que o que o find_root encontrou. Ele mostra a primeira que encontra.

Poderíamos encontar a outra restringindo o intervalo (min, max)

In [49]:

find_root(expr,.1,pi/2+.1)

Out[49]:

$\newcommand{\Bold}[1]{\mathbf{#1}}1.570796326794898$

Função	Sintáxe
Solução simbólica	`solve(equação, variável)`
Solução numérica	`find_root(equação, min, manx)`

Exercícios¶

Defina um polinômio de grau 2 na forma $p(x) = ax^2+bx+c$ . Lembre-se de definir as variáveis simbólicas antes. Agora use o solve para encontrar as soluções $p(x)=0$ .

In [ ]:

6. Ferramentas de cálculo¶

6.1 Derivadas¶

Simples

In [50]:

diff(sin(x^2),x)

Out[50]:

$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, x \cos\left(x^{2}\right)$

de ordem superior

In [51]:

diff(sin(x^2), x,3)

Out[51]:

$\newcommand{\Bold}[1]{\mathbf{#1}}-8 \, x^{3} \cos\left(x^{2}\right) - 12 \, x \sin\left(x^{2}\right)$

parcial

In [52]:

h(x,y) = x*y^2 + sin(x^2) + e^(-x); h(x,y)

Out[52]:

$\newcommand{\Bold}[1]{\mathbf{#1}}x y^{2} + e^{\left(-x\right)} + \sin\left(x^{2}\right)$

In [53]:

diff(h(x,y), x)

Out[53]:

$\newcommand{\Bold}[1]{\mathbf{#1}}y^{2} + 2 \, x \cos\left(x^{2}\right) - e^{\left(-x\right)}$

In [54]:

diff(h(x,y), y)

Out[54]:

$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, x y$

6.2 Integrais¶

In [55]:

g(x) = 1/(1+x^2)

In [56]:

integral(g(x),x, -infinity, infinity,hold=True)

Out[56]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\int_{-\infty}^{+\infty} \frac{1}{x^{2} + 1}\,{d x}$

In [57]:

integral(g(x),x, -infinity, infinity)

Out[57]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\pi$

In [58]:

var('G M r c')
integrate(1-2*G*M/(c^2*r), r)

Out[58]:

$\newcommand{\Bold}[1]{\mathbf{#1}}r - \frac{2 \, G M \log\left(r\right)}{c^{2}}$

In [59]:

diff(_,r)

Out[59]:

$\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{2 \, G M}{c^{2} r} + 1$

6.3 Integração numérica¶

Para calcular numericamente uma integral usamos a função integral_numerical.

Essa função retorna um par:

o primeiro valor é a aproximação da integral;

o segundo uma estimativa do erro correspondente.

In [60]:

integral_numerical(sin(x)/x, 0, 1)

Out[60]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\left(0.946083070367183, 1.0503632079297087 \times 10^{-14}\right)$

In [61]:

integral(sin(x)/x,x, 0, 1)

Out[61]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\operatorname{Si}\left(1\right)$

In [62]:

integral(sin(x)/x,x, 0, 1).n()

Out[62]:

$\newcommand{\Bold}[1]{\mathbf{#1}}0.946083070367183$

In [63]:

sin_integral?

6.4 Séries de Taylor¶

In [64]:

taylor(f(x), x, 0, 3)

Out[64]:

$\newcommand{\Bold}[1]{\mathbf{#1}}1$

In [ ]:

Função	Sintáxe
Limite	`lim(f(x),x=a)` ou `limit(f(x),x=a)`
Derivada	`diff(f(x), x)` ou `f(x).diff()`
n-ésima derivada	`diff(f(x), x, n)`
Integral indefinida	`integral(f(x), x)`
Integral definida	`integral(f(x), x, lim_inf, lim_sup)`
Integral numérica	`integral_numerical(f(x), lim_inf, lim_sup)`
Série de Taylor	`taylor(f(x), x, x_0, ordem)`

7. Substituições em expressões simbólicas¶

Uma funcionalidade muito útil em cálculos simbólicos é a substituição de exprssões com o método .subs().

In [65]:

var('A B C D')
a = A+B;a

Out[65]:

$\newcommand{\Bold}[1]{\mathbf{#1}}A + B$

In [66]:

a.subs(A==D)

Out[66]:

$\newcommand{\Bold}[1]{\mathbf{#1}}B + D$

In [67]:

f(x) = A*x^2+B*x+C;f(x)

Out[67]:

$\newcommand{\Bold}[1]{\mathbf{#1}}A x^{2} + B x + C$

In [68]:

f(x).subs(A==1,B==5,C==9)

Out[68]:

$\newcommand{\Bold}[1]{\mathbf{#1}}x^{2} + 5 \, x + 9$

In [69]:

b = diff(f(x),x)+cos(x);b

Out[69]:

$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, A x + B + \cos\left(x\right)$

In [70]:

b.subs(cos(x)==2)

Out[70]:

$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, A x + B + 2$

Podemos introduzir funções com expressão não definida

In [71]:

h = function('h')(x);h

Out[71]:

$\newcommand{\Bold}[1]{\mathbf{#1}}h\left(x\right)$

In [72]:

c = diff(h(x),x,2)+2*f(3*x)^2;c

Out[72]:

$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left(9 \, A x^{2} + 3 \, B x + C\right)}^{2} + \frac{\partial^{2}}{(\partial x)^{2}}h\left(x\right)$

In [73]:

c.subs(diff(h(x),x,2)==x/pi)

Out[73]:

$\newcommand{\Bold}[1]{\mathbf{#1}}2 \, {\left(9 \, A x^{2} + 3 \, B x + C\right)}^{2} + \frac{x}{\pi}$

8. Equações diferenciais ordinárias¶

In [74]:

y = function('y')(x);y

Out[74]:

$\newcommand{\Bold}[1]{\mathbf{#1}}y\left(x\right)$

In [75]:

ed_1 = diff(y,x) == (cos(y)-2*x)/(y+x*sin(y)); ed_1

Out[75]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{\partial}{\partial x}y\left(x\right) = -\frac{2 \, x - \cos\left(y\left(x\right)\right)}{x \sin\left(y\left(x\right)\right) + y\left(x\right)}$

Lembrando que para resolver equações diferenciais usamos desolve(equação, dvar, ivar=t), onde dvar é a variável dependente e ivar=t indica que a variável independente e $t$

In [76]:

sol_ed = desolve(ed_1, y); sol_ed

Out[76]:

$\newcommand{\Bold}[1]{\mathbf{#1}}x^{2} - x \cos\left(y\left(x\right)\right) + \frac{1}{2} \, y\left(x\right)^{2} = C$

Podemos plotar a função usando o implicit_plot

O comando implicit_plot recebe uma função de duas variáveis como entrada, $f(x, y)$ , e plota a curva $f(x, y) = 0$ sobre os intervalo de $x$ e y especificados. Sintáxe implicit_plot(f(x,y),(x,xmin,xmax),(y,ymin,ymax), *opções)

In [77]:

var('u')
sol_ed2 = sol_ed.lhs().subs(y(x)==u);sol_ed2

Out[77]:

$\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{2} \, u^{2} + x^{2} - x \cos\left(u\right)$

In [78]:

plot_sol = implicit_plot(sol_ed2, (x,-.5,1), (u,-.7,.7), color=(0,.5,1), axes_labels=['$x$','$u$']); plot_sol

Out[78]:

Com campo

In [79]:

plot_campos = plot_slope_field(ed_1.rhs().subs({y(x):u}), (x,-1.5,2), (u,-1.5,1.5));plot_campos

Out[79]:

In [80]:

plot_sol+plot_campos

Out[80]:

Exercícios¶

Determine o valor de $\frac{\partial f}{\partial u}(0,1,1)$ , para

$f(s,t,u)=\frac{s+tu}{\sqrt{s^2+t^2+u^2}}$

In [ ]:

Dadas as equações de transformação de coordenadas cartesianas para esféficas, já definidas abaixo, manipule simbolicamente estas equações de modo a transformação inversa. Isto é, $r(x,y,z), \theta(x,y,z)$ e $\phi(x,y,z)$ .

In [81]:

var('y z r theta phi')
eqx = x == r*sin(theta)*cos(phi)
eqy = y == r*sin(theta)*sin(phi)
eqz = z == r*cos(theta)

In [ ]:

Seja $g$ a aceleração da gravidade na superfície da Terra. Em termos da teoria de Newton, se $R$ é o raio da terra e $M$ sua massa,

$g = \frac{GM}{R^2}.$

Determine a expansão de até terceira ordem para a modificação em $g$ a uma altura $h$ acima da superfície da terra.

In [ ]: