DFTK is a Julia package for playing with plane-wave density-functional theory algorithms. In its basic formulation it solves periodic Kohn-Sham equations.
This document provides an overview of the structure of the code and how to access basic information about calculations. Basic familiarity with the concepts of plane-wave density functional theory is assumed throughout. Feel free to take a look at the Periodic problems or the density-functional theory chapters for some introductory material on the topic.
!!! note "Convergence parameters in the documentation" We use rough parameters in order to be able to automatically generate this documentation very quickly. Therefore results are far from converged. Tighter thresholds and larger grids should be used for more realistic results.
For our discussion we will use the classic example of computing the LDA ground state of the silicon crystal. Performing such a calculation roughly proceeds in three steps.
using DFTK
using Plots
using Unitful
using UnitfulAtomic
# 1. Define lattice and atomic positions
a = 5.431u"angstrom" # Silicon lattice constant
lattice = a / 2 * [[0 1 1.]; # Silicon lattice vectors
[1 0 1.]; # specified column by column
[1 1 0.]]
3×3 Matrix{Unitful.Quantity{Float64, 𝐋, Unitful.FreeUnits{(Å,), 𝐋, nothing}}}: 0.0 Å 2.7155 Å 2.7155 Å 2.7155 Å 0.0 Å 2.7155 Å 2.7155 Å 2.7155 Å 0.0 Å
By default, all numbers passed as arguments are assumed to be in atomic units. Quantities such as temperature, energy cutoffs, lattice vectors, and the k-point grid spacing can optionally be annotated with Unitful units, which are automatically converted to the atomic units used internally. For more details, see the Unitful package documentation and the UnitfulAtomic.jl package.
# Load HGH pseudopotential for Silicon
Si = ElementPsp(:Si, psp=load_psp("hgh/lda/Si-q4"))
# Specify type and positions of atoms
atoms = [Si, Si]
positions = [ones(3)/8, -ones(3)/8]
# 2. Select model and basis
model = model_LDA(lattice, atoms, positions)
kgrid = [4, 4, 4] # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 7 # kinetic energy cutoff
# Ecut = 190.5u"eV" # Could also use eV or other energy-compatible units
basis = PlaneWaveBasis(model; Ecut, kgrid)
# Note the implicit passing of keyword arguments here:
# this is equivalent to PlaneWaveBasis(model; Ecut=Ecut, kgrid=kgrid)
# 3. Run the SCF procedure to obtain the ground state
scfres = self_consistent_field(basis, tol=1e-8);
n Energy log10(ΔE) log10(Δρ) Diag --- --------------- --------- --------- ---- 1 -7.900414412069 -0.70 4.1 2 -7.905010926090 -2.34 -1.52 1.0 3 -7.905210802115 -3.70 -2.52 3.1 4 -7.905211517180 -6.15 -3.34 2.9 5 -7.905211530341 -7.88 -4.66 1.4 6 -7.905211531396 -8.98 -5.16 3.9
That's it! Now you can get various quantities from the result of the SCF. For instance, the different components of the energy:
scfres.energies
Energy breakdown (in Ha): Kinetic 3.1020979 AtomicLocal -2.1987873 AtomicNonlocal 1.7296101 Ewald -8.3979253 PspCorrection -0.2946254 Hartree 0.5530400 Xc -2.3986216 total -7.905211531396
Eigenvalues:
hcat(scfres.eigenvalues...)
7×8 Matrix{Float64}: -0.176942 -0.14744 -0.0911692 … -0.101219 -0.023977 -0.0184079 0.261073 0.116915 0.00482515 0.0611644 -0.023977 -0.0184079 0.261073 0.23299 0.216733 0.121636 0.155532 0.117747 0.261073 0.23299 0.216733 0.212134 0.155532 0.117747 0.354532 0.335109 0.317102 0.350436 0.285692 0.417258 0.354532 0.389829 0.384601 … 0.436925 0.285692 0.4175 0.354532 0.389829 0.384601 0.449266 0.62753 0.443806
eigenvalues
is an array (indexed by k-points) of arrays (indexed by
eigenvalue number). The "splatting" operation ...
calls hcat
with all the inner arrays as arguments, which collects them into a
matrix.
The resulting matrix is 7 (number of computed eigenvalues) by 8
(number of k-points). There are 7 eigenvalues per k-point because
there are 4 occupied states in the system (4 valence electrons per
silicon atom, two atoms per unit cell, and paired spins), and the
eigensolver gives itself some breathing room by computing some extra
states (see n_ep_extra
argument to self_consistent_field
).
We can check the occupations ...
hcat(scfres.occupation...)
7×8 Matrix{Float64}: 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 2.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0
... and density, where we use that the density objects in DFTK are indexed as ρ[iσ, ix, iy, iz], i.e. first in the spin component and then in the 3-dimensional real-space grid.
rvecs = collect(r_vectors(basis))[:, 1, 1] # slice along the x axis
x = [r[1] for r in rvecs] # only keep the x coordinate
plot(x, scfres.ρ[1, :, 1, 1], label="", xlabel="x", ylabel="ρ", marker=2)
We can also perform various postprocessing steps: for instance compute a band structure
plot_bandstructure(scfres; kline_density=10)
Computing bands along kpath: Γ -> X -> U and K -> Γ -> L -> W -> X Diagonalising Hamiltonian kblocks: 100%|████████████████| Time: 0:00:00
or get the cartesian forces (in Hartree / Bohr)
compute_forces_cart(scfres)
2-element Vector{StaticArrays.SVector{3, Float64}}: [-2.191509554957525e-16, -6.001040450720518e-16, 2.7378380023287873e-16] [-4.5585489959038625e-16, -2.5011191789770235e-17, 1.7892568072338752e-16]
As expected, they are almost zero in this highly symmetric configuration.
Take a look at the example index to continue exploring DFTK.