In this example, we show how to define custom solvers. Our system will again be silicon, because we are not very imaginative
using DFTK, LinearAlgebra
a = 10.26
lattice = a / 2 * [[0 1 1.];
[1 0 1.];
[1 1 0.]]
Si = ElementPsp(:Si, psp=load_psp("hgh/lda/Si-q4"))
atoms = [Si => [ones(3)/8, -ones(3)/8]]
# We take very (very) crude parameters
model = model_LDA(lattice, atoms)
kgrid = [1, 1, 1]
Ecut = 5
basis = PlaneWaveBasis(model, Ecut; kgrid=kgrid);
We define our custom fix-point solver: simply a damped fixed-point
function my_fp_solver(f, x0, max_iter; tol)
mixing_factor = .7
x = x0
fx = f(x)
for n = 1:max_iter
inc = fx - x
if norm(inc) < tol
break
end
x = x + mixing_factor * inc
fx = f(x)
end
(fixpoint=x, converged=norm(fx-x) < tol)
end;
Our eigenvalue solver just forms the dense matrix and diagonalizes it explicitly (this only works for very small systems)
function my_eig_solver(A, X0; maxiter, tol, kwargs...)
n = size(X0, 2)
A = Array(A)
E = eigen(A)
λ = E.values[1:n]
X = E.vectors[:, 1:n]
(λ=λ, X=X, residual_norms=[], iterations=0, converged=true, n_matvec=0)
end;
Finally we also define our custom mixing scheme. It will be a mixture
of simple mixing (for the first 2 steps) and than default to Kerker mixing.
In the mixing interface δF
is (ρ_\text{out} - ρ_\text{in})
, i.e.
the difference in density between two subsequent SCF steps and the mix
function returns δρ
, which is added to ρ_\text{in}
to yield ρ_\text{next}
,
the density for the next SCF step.
struct MyMixing
n_simple # Number of iterations for simple mixing
end
MyMixing() = MyMixing(2)
function DFTK.mix(mixing::MyMixing, basis, δF; n_iter, kwargs...)
if n_iter <= mixing.n_simple
return δF # Simple mixing -> Do not modify update at all
else
# Use the default KerkerMixing from DFTK
DFTK.mix(KerkerMixing(), basis, δF; kwargs...)
end
end
That's it! Now we just run the SCF with these solvers
scfres = self_consistent_field(basis;
tol=1e-8,
solver=my_fp_solver,
eigensolver=my_eig_solver,
mixing=MyMixing());
n Energy Eₙ-Eₙ₋₁ ρout-ρin Diag --- --------------- --------- -------- ---- 1 -7.191131155440 NaN 3.59e-01 0.0 2 -7.241011880139 -4.99e-02 1.66e-01 0.0 3 -7.248650835000 -7.64e-03 5.84e-02 0.0 4 -7.249084675018 -4.34e-04 2.86e-02 0.0 5 -7.249185479474 -1.01e-04 1.43e-02 0.0 6 -7.249209123174 -2.36e-05 7.27e-03 0.0 7 -7.249214867277 -5.74e-06 3.76e-03 0.0 8 -7.249216334001 -1.47e-06 1.98e-03 0.0 9 -7.249216730457 -3.96e-07 1.06e-03 0.0 10 -7.249216843968 -1.14e-07 5.77e-04 0.0 11 -7.249216878232 -3.43e-08 3.18e-04 0.0 12 -7.249216889049 -1.08e-08 1.78e-04 0.0 13 -7.249216892588 -3.54e-09 1.00e-04 0.0
Note that the default convergence criterion is on the difference of
energy from one step to the other; when this gets below tol
, the
"driver" self_consistent_field
artificially makes the fixpoint
solver think it's converged by forcing f(x) = x
. You can customize
this with the is_converged
keyword argument to
self_consistent_field
.