In this example, we show how to define custom solvers. Our system will again be silicon, because we are not very imaginative
using DFTK, LinearAlgebra
a = 10.26
lattice = a / 2 * [[0 1 1.];
[1 0 1.];
[1 1 0.]]
Si = ElementPsp(:Si, psp=load_psp("hgh/lda/Si-q4"))
atoms = [Si => [ones(3)/8, -ones(3)/8]]
# We take very (very) crude parameters
model = model_LDA(lattice, atoms)
kgrid = [1, 1, 1]
Ecut = 5
basis = PlaneWaveBasis(model, Ecut; kgrid=kgrid);
We define our custom fix-point solver: simply a damped fixed-point
function my_fp_solver(f, x0, max_iter; tol)
mixing_factor = .7
x = x0
fx = f(x)
for n = 1:max_iter
inc = fx - x
if norm(inc) < tol
break
end
x = x + mixing_factor * inc
fx = f(x)
end
(fixpoint=x, converged=norm(fx-x) < tol)
end;
Our eigenvalue solver just forms the dense matrix and diagonalizes it explicitly (this only works for very small systems)
function my_eig_solver(A, X0; maxiter, tol, kwargs...)
n = size(X0, 2)
A = Array(A)
E = eigen(A)
λ = E.values[1:n]
X = E.vectors[:, 1:n]
(λ=λ, X=X, residual_norms=[], iterations=0, converged=true, n_matvec=0)
end;
Finally we also define our custom mixing scheme. It will be a mixture
of simple mixing (for the first 2 steps) and than default to Kerker mixing.
In the mixing interface δF
is (ρ_\text{out} - ρ_\text{in})
, i.e.
the difference in density between two subsequent SCF steps and the mix
function returns δρ
, which is added to ρ_\text{in}
to yield ρ_\text{next}
,
the density for the next SCF step.
struct MyMixing
α # Damping parameter
end
MyMixing() = MyMixing(0.7)
function DFTK.mix(mixing::MyMixing, basis, δF::RealFourierArray, δF_spin=nothing; n_iter, kwargs...)
if n_iter <= 2
# Just do simple mixing on total density and spin density (if it exists)
(mixing.α * δF, isnothing(δF_spin) ? nothing : mixing.α * δF_spin)
else
# Use the KerkerMixing from DFTK
DFTK.mix(KerkerMixing(α=mixing.α), basis, δF, δF_spin; kwargs...)
end
end
That's it! Now we just run the SCF with these solvers
scfres = self_consistent_field(basis;
tol=1e-8,
solver=my_fp_solver,
eigensolver=my_eig_solver,
mixing=MyMixing());
n Energy Eₙ-Eₙ₋₁ ρout-ρin Diag --- --------------- --------- -------- ---- 1 -7.233156188874 NaN 3.19e-01 0.0 2 -7.246429449815 -1.33e-02 1.46e-01 0.0 3 -7.248781365551 -2.35e-03 6.61e-02 0.0 4 -7.249072828022 -2.91e-04 3.64e-02 0.0 5 -7.249168999888 -9.62e-05 2.02e-02 0.0 6 -7.249200686794 -3.17e-05 1.13e-02 0.0 7 -7.249211270992 -1.06e-05 6.40e-03 0.0 8 -7.249214887144 -3.62e-06 3.67e-03 0.0 9 -7.249216157016 -1.27e-06 2.14e-03 0.0 10 -7.249216616123 -4.59e-07 1.26e-03 0.0 11 -7.249216786860 -1.71e-07 7.57e-04 0.0 12 -7.249216852002 -6.51e-08 4.60e-04 0.0 13 -7.249216877412 -2.54e-08 2.83e-04 0.0 14 -7.249216887507 -1.01e-08 1.76e-04 0.0 15 -7.249216891577 -4.07e-09 1.11e-04 0.0
Note that the default convergence criterion is on the difference of
energy from one step to the other; when this gets below tol
, the
"driver" self_consistent_field
artificially makes the fixpoint
solver think it's converged by forcing f(x) = x
. You can customize
this with the is_converged
keyword argument to
self_consistent_field
.