In this example we consider iron in the BCC phase. To show that this material is ferromagnetic we will model it once allowing collinear spin polarization and once without and compare the resulting SCF energies. In particular the ground state can only be found if collinear spins are allowed.
First we setup BCC iron without spin polarization using a single iron atom inside the unit cell.
using DFTK
a = 5.42352 # Bohr
lattice = a / 2 * [[-1 1 1];
[ 1 -1 1];
[ 1 1 -1]]
atoms = [ElementPsp(:Fe; psp=load_psp("hgh/lda/Fe-q8.hgh"))]
positions = [zeros(3)];
To get the ground-state energy we use an LDA model and rather moderate discretisation parameters.
kgrid = [3, 3, 3] # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 15 # kinetic energy cutoff in Hartree
model_nospin = model_LDA(lattice, atoms, positions, temperature=0.01)
basis_nospin = PlaneWaveBasis(model_nospin; kgrid, Ecut)
scfres_nospin = self_consistent_field(basis_nospin; tol=1e-4, mixing=KerkerDosMixing());
n Energy log10(ΔE) log10(Δρ) Diag Δtime --- --------------- --------- --------- ---- ------ 1 -16.65003046484 -0.48 5.8 116ms 2 -16.65071592420 -3.16 -1.01 1.0 2.34s 3 -16.65081656222 -4.00 -2.31 1.8 19.6ms 4 -16.65082427822 -5.11 -2.85 1.8 20.1ms 5 -16.65082465691 -6.42 -3.38 1.5 19.0ms 6 -16.65082469421 -7.43 -4.00 1.8 20.3ms 7 -16.65082469745 -8.49 -4.39 1.8 33.3ms
scfres_nospin.energies
Energy breakdown (in Ha): Kinetic 15.9208002 AtomicLocal -5.0693024 AtomicNonlocal -5.2202038 Ewald -21.4723040 PspCorrection 1.8758831 Hartree 0.7793381 Xc -3.4467480 Entropy -0.0182879 total -16.650824697448
Since we did not specify any initial magnetic moment on the iron atom, DFTK will automatically assume that a calculation with only spin-paired electrons should be performed. As a result the obtained ground state features no spin-polarization.
Now we repeat the calculation, but give the iron atom an initial magnetic moment.
For specifying the magnetic moment pass the desired excess of spin-up over spin-down
electrons at each centre to the Model
and the guess density functions.
In this case we seek the state with as many spin-parallel
$d$-electrons as possible. In our pseudopotential model the 8 valence
electrons are 1 pair of $s$-electrons, 1 pair of $d$-electrons
and 4 unpaired $d$-electrons giving a desired magnetic moment of 4
at the iron centre.
The structure (i.e. pair mapping and order) of the magnetic_moments
array needs to agree
with the atoms
array and 0
magnetic moments need to be specified as well.
magnetic_moments = [4];
!!! tip "Units of the magnetisation and magnetic moments in DFTK" Unlike all other quantities magnetisation and magnetic moments in DFTK are given in units of the Bohr magneton $μ_B$, which in atomic units has the value $\frac{1}{2}$. Since $μ_B$ is (roughly) the magnetic moment of a single electron the advantage is that one can directly think of these quantities as the excess of spin-up electrons or spin-up electron density.
We repeat the calculation using the same model as before. DFTK now detects the non-zero moment and switches to a collinear calculation.
model = model_LDA(lattice, atoms, positions; magnetic_moments, temperature=0.01)
basis = PlaneWaveBasis(model; Ecut, kgrid)
ρ0 = guess_density(basis, magnetic_moments)
scfres = self_consistent_field(basis, tol=1e-6; ρ=ρ0, mixing=KerkerDosMixing());
n Energy log10(ΔE) log10(Δρ) Magnet Diag Δtime --- --------------- --------- --------- ------ ---- ------ 1 -16.66166510264 -0.51 2.617 4.9 61.1ms 2 -16.66825580242 -2.18 -1.09 2.445 1.5 1.51s 3 -16.66905411049 -3.10 -2.07 2.341 2.0 40.7ms 4 -16.66909852203 -4.35 -2.63 2.305 1.2 35.2ms 5 -16.66910304202 -5.34 -3.01 2.295 1.8 49.6ms 6 -16.66910414276 -5.96 -3.52 2.287 1.6 38.9ms 7 -16.66910417185 -7.54 -3.79 2.286 1.9 39.9ms 8 -16.66910417423 -8.62 -4.32 2.286 1.4 36.7ms 9 -16.66910417511 -9.06 -4.79 2.286 1.6 40.7ms 10 -16.66910417505 + -10.28 -5.15 2.286 1.6 38.8ms 11 -16.66910417508 -10.62 -5.66 2.286 1.2 37.6ms 12 -16.66910417508 -11.14 -6.34 2.286 2.0 42.4ms
scfres.energies
Energy breakdown (in Ha): Kinetic 16.2947171 AtomicLocal -5.2227247 AtomicNonlocal -5.4100269 Ewald -21.4723040 PspCorrection 1.8758831 Hartree 0.8191958 Xc -3.5406833 Entropy -0.0131612 total -16.669104175085
!!! note "Model and magnetic moments"
DFTK does not store the magnetic_moments
inside the Model
, but only uses them
to determine the lattice symmetries. This step was taken to keep Model
(which contains the physical model) independent of the details of the numerical details
such as the initial guess for the spin density.
In direct comparison we notice the first, spin-paired calculation to be a little higher in energy
println("No magnetization: ", scfres_nospin.energies.total)
println("Magnetic case: ", scfres.energies.total)
println("Difference: ", scfres.energies.total - scfres_nospin.energies.total);
No magnetization: -16.65082469744767 Magnetic case: -16.669104175084914 Difference: -0.018279477637243247
Notice that with the small cutoffs we use to generate the online documentation the calculation is far from converged. With more realistic parameters a larger energy difference of about 0.1 Hartree is obtained.
The spin polarization in the magnetic case is visible if we consider the occupation of the spin-up and spin-down Kohn-Sham orbitals. Especially for the $d$-orbitals these differ rather drastically. For example for the first $k$-point:
iup = 1
idown = iup + length(scfres.basis.kpoints) ÷ 2
@show scfres.occupation[iup][1:7]
@show scfres.occupation[idown][1:7];
(scfres.occupation[iup])[1:7] = [1.0, 0.9999987814418424, 0.9999987814418424, 0.9999987814418424, 0.9582253220316017, 0.9582253220315997, 1.1266362554694239e-29] (scfres.occupation[idown])[1:7] = [1.0, 0.8438934035793637, 0.8438934035793278, 0.8438934035792146, 8.140862627921028e-6, 8.140862627919205e-6, 1.6228414541189837e-32]
Similarly the eigenvalues differ
@show scfres.eigenvalues[iup][1:7]
@show scfres.eigenvalues[idown][1:7];
(scfres.eigenvalues[iup])[1:7] = [-0.06935855528529075, 0.35688569071558707, 0.3568856907155941, 0.35688569071560294, 0.46173617504165976, 0.46173617504166026, 1.159621413577478] (scfres.eigenvalues[idown])[1:7] = [-0.03125746766732285, 0.47618922985941115, 0.47618922985941387, 0.47618922985942247, 0.6102501635791894, 0.6102501635791916, 1.2250495446817087]
!!! note "$k$-points in collinear calculations"
For collinear calculations the kpoints
field of the PlaneWaveBasis
object contains
each $k$-point coordinate twice, once associated with spin-up and once with down-down.
The list first contains all spin-up $k$-points and then all spin-down $k$-points,
such that iup
and idown
index the same $k$-point, but differing spins.
We can observe the spin-polarization by looking at the density of states (DOS) around the Fermi level, where the spin-up and spin-down DOS differ.
using Plots
bands_666 = compute_bands(scfres, MonkhorstPack(6, 6, 6)) # Increase kgrid to get nicer DOS.
plot_dos(bands_666)
Note that if same k-grid as SCF should be employed, a simple plot_dos(scfres)
is sufficient.
Similarly the band structure shows clear differences between both spin components.
using Unitful
using UnitfulAtomic
bands_kpath = compute_bands(scfres; kline_density=6)
plot_bandstructure(bands_kpath)